#!/pkg/gnu/bin/gawk -f
BEGIN {
  #
  # this script regulates the play of ronald loui's and anne jump's game
  # which is intended to model the following aspects of negotiation
  # which are absent in game-theoretic approaches:
  #
  #	re:  search
  # the creation of focal points through dialogue and search
  # interplay of individual and social search
  # joint problem-solving through resource exchange and search
  # cost of search and heuristic/satisficing search
  # multidimensionality of settlement options generated, not predefined
  #
  #	re:  language
  # explicit threats and queries
  # unrestricted language
  #
  #	re:  purpose
  # multiplicity of winning conditions
  #
  #	re:  method
  # importance of design not analysis
  # importance of process not outcome
  # importance of player input to a process, not equilibria
  #

  # this game was developed during the summer of 1997 by ronald p. loui
  # and anne h. jump, a consultant, funded by the national science foundation
  # program on information technology and organizations within the
  # information, robotics, and intelligent systems division of the
  # computer and information systems engineering directorate.

  # version 4.3 of 1/98 rpl
  # 1.0 attempts as clean code as possible for basic functionality
  # 2.0 MAJOR REVISION:  permits programs to be used to generate commands
  # 2.1 can pipe output to /dev/stdout and file for programs to read
  # 2.2 implements otake
  # 2.3 puts limit on how long to negotiate
  # 2.4 implements the verbose option
  # 2.5 fixes a bug that lets you accept your own proposals
  # 2.6 contains all the code needed to run as a tournament
  # 3.0 of 12/97 permits gui monitoring of negotiation
  # 4.0 MAJOR REVISION sends output to the web
  # 4.1 MAJOR REVISION reads, processes a single command, then saves
  # 4.2 cleaner HTML table, input mostly separate from payoff presentation
  # 4.3 MAJOR REVISION abstracts players' names (anne --> playerA)

  # 5.0 MAJOR REVISION to rules of the game:  pilecardmin

  verbose = 1
  gui = 0
  webout = 1
  cgidebug = 1

  print "<pre>"

  playerAprog = ARGV[1]
  playerBprog = ARGV[2]
  pairing = ARGV[3]

  # each program takes a view.playerB or view.playerA and generates a move
  # assume these programs are executable, and paired with X.howhappy, which is also executable

  if (playerAprog ~ "---") playerAprog = ""
  if (playerBprog ~ "---") playerBprog = ""

  if (playerAprog) { playerAcom = playerAprog " playerA" }
  if (playerBprog) { playerBcom = playerBprog " playerB" }

  # this may need to be set differently for tournament or cgi
  PATH = "/home/cs/faculty/loui/.www-docs/313f97/"
  PATH = "./"
  savefile = PATH "anne.save"
  dialoguefile = PATH "anne.dialogue"

  srand()

  if (restore()) {
    print "restoring"
  } else {
    print "reinitializing"
    if (rand() < .5) whoseturn = "playerA"
    else whoseturn = "playerB"
    init()
    deal()
    revealsomecards()
    save()
    if (webout) viewweb()
    # don't process input on a reinitialization
    exit
  }

  if (negotiate(1)) {
    revealremaining()
    if (webout) finalweb()
    if (verbose) view("playerA and playerB","/dev/stdout")
    traderesources()
    doexchanges()
    if (verbose) view("playerA and playerB","/dev/stdout")
    sumcells()
    reportsums()
    reportvalue(finalrow,finalcol)
    askhowhappy()
  
    score()
    makesocialrecord()

  } else save()

  if (cgidebug) print "CGIDEBUG normal exit"

}

function finalweb( i) {
  prhtml("<I>A Better Negotiation Game</I>, designed by R.P. Loui and A.H. Jump, Summer 1997.")
  prhtml("<BR><BR><BR>")
  prhtml("<CENTER><H2>FINAL OUTCOME</H2>") 
  prhtml("<A HREF='anne4.expl.html'>EXPLANATION</A>")
  prhtml("<FORM METHOD='post' ACTION='anne4.cgi'>")
  timestampthisform()
  prhtml("<input type=submit value='START A NEW GAME'>")
  prhtml("</FORM></CENTER>")
  viewwebhow("playerA",1) 
  viewwebhow("playerB",1)
  # don't close because values will be reported

  # erase the savefile
  close(savefile)
  print "" > savefile
  close(savefile)
}

function save( i,j,ntemp) {
  # rows, cols
  # playerA, playerB
  # annresources
  # playerBresources
  # count:
  # resources
  # count:
  # proposals
  # count:
  # sidepayments
  # count:
  # sidetakings
  # whoseturn
  # forcingperson
  # finalrow
  # finalcol
  # plies
  # search stats
  print rows, cols > savefile
  for (i=1; i<=rows; i++) for (j=1; j<=cols; j++) print playerA[i,j], playerB[i,j] > savefile

  print playerAresources > savefile
  print playerBresources > savefile

  ntemp = 0
  for (i in resources) if (resources[i]) ntemp++
  print ntemp, "resources" > savefile
  for (i in resources) if (resources[i]) print i,resources[i] > savefile
  ntemp = 0
  for (i in activeprop) if (activeprop[i]) ntemp++
  print ntemp, "activeprop" > savefile
  for (i in activeprop) if (activeprop[i]) print i,activeprop[i] > savefile
  ntemp = 0
  for (i in sidepay) ntemp++
  print ntemp, "sidepay" > savefile
  for (i in sidepay) print i,sidepay[i] > savefile
  ntemp = 0
  for (i in sidetake) ntemp++
  print ntemp, "sidetake"  > savefile
  for (i in sidetake) print i,sidetake[i] > savefile

  print whoseturn, "whoseturn" > savefile
  print forcingperson > savefile
  print finalrow > savefile
  print finalcol > savefile
  print plies > savefile
  print maxplies > savefile
  print playerAfree > savefile
  print playerAfreeused > savefile
  print playerAcost > savefile
  print playerAcostused > savefile
  print playerBfree > savefile
  print playerBfreeused > savefile
  print playerBcost > savefile
  print playerBcostused > savefile
  close(savefile)
}

function restore( i,j,ntemp) {
  if ((getline < savefile) == -1) return 0
  # actually, need an empty file to save write-permissions
  if (!$0) return 0 
  rows = $1; cols = $2
  for (i=1; i<=rows; i++) for (j=1; j<=cols; j++) {
    getline < savefile
    playerA[i,j] = $1; playerB[i,j] = $2
  }
  getline playerAresources < savefile
  getline playerBresources < savefile

  getline < savefile
  ntemp = $1
  for (i=1; i<=ntemp; i++) {
    getline < savefile
    resources[$1] = $2
  }
  getline < savefile
  ntemp = $1
  for (i=1; i<=ntemp; i++) {
    getline < savefile
    activeprop[$1] = $2
  }
  getline < savefile
  ntemp = $1
  for (i=1; i<=ntemp; i++) {
    getline < savefile
    sidepay[$1] = $2
  }
  getline < savefile
  ntemp = $1
  for (i=1; i<=ntemp; i++) {
    getline < savefile
    sidetake[$1] = $2
  }

  getline < savefile
  whoseturn = $1
  getline forcingperson < savefile
  getline finalrow < savefile
  getline finalcol < savefile
  getline plies < savefile
  getline maxplies < savefile
  getline playerAfree < savefile
  getline playerAfreeused < savefile
  getline playerAcost < savefile
  getline playerAcostused < savefile
  getline playerBfree < savefile
  getline playerBfreeused < savefile
  getline playerBcost < savefile
  getline playerBcostused < savefile

  close(savefile)

  return 1
}

function report(x) {
  print x
  violation = x
}

function negotiate(oneturn) {
  # the oneturn flag restricts this to one input
  # returns 1 if agreement/breakdown

  # if (rand() < .5) whoseturn = "playerA"
  # else whoseturn = "playerB"
  do {
    plies++
    if (plies > maxplies) {
      print "negotiation too long... exiting!", plies
      exit
    }

    if (verbose) {
      print "\t\t\t\t_______________"
      print "\n\t\t\t\t  "whoseturn"'s turn"
      print "\t\t\t\t_______________"
      view(whoseturn,"/dev/stdout")
    }

    if (cgidebug) print "CGIDEBUG beginning program views"
    if (playerAprog || playerBprog) view(whoseturn,outfile(whoseturn))

    # if (verbose) if (++turn <= 2) printmenu()
    if (gui) viewgui()

    if (forcingperson == whoseturn) {
      print whoseturn" has left the negotiation with "
      print lastforce
      $0 = lastforce
      savecommand = $0

    } else if (playerAprog && whoseturn ~ /playerA/) {
      playerAcom | getline
      savecommand = $0
      close(playerAcom)
      # protect from spies
      # system("rm -f "outfile(whoseturn))
      violation = ""
      command()
    } else if (playerBprog && whoseturn ~ /playerB/) {
      playerBcom | getline
      savecommand = $0
      close(playerBcom)
      # protect from spies
      # system("rm -f "outfile(whoseturn))
      violation = ""
      command()

    } else {
      printf "\t\t\t"whoseturn"'s action (or 'menu' or 'redraw')?"; getline
      savecommand = $0
      if ($0 ~ /menu/) {
	printmenu()
        printf "\t\t\t\t"whoseturn"'s action (or 'redraw')?"; getline
      }
      if ($0 ~ /redraw/) {
	continue
      } else {
        resultingview = 0; # could be set to 1 in command
	violation = ""
	command()
      }
    }

    if (cgidebug) print "CGIDEBUG updating dialogue"
    addtodialogue(savecommand)
    if (cgidebug) print "CGIDEBUG updated dialogue"

    if (verbose) if (resultingview) view(whoseturn,"/dev/stdout")

    if (whoseturn == "playerA") whoseturn = "playerB"
    else whoseturn = "playerA"

    if (forcingperson) whoseturn = otherplayer(forcingperson)

    if (cgidebug) print "CGIDEBUG updating webout"
    if (webout) viewweb()
    if (cgidebug) print "CGIDEBUG updated webout"

  } while ((!agreement && !oneturn) || savecommand ~ /redraw/)

  if (cgidebug) print "CGIDEBUG normal return from negotiate"
  return agreement
}

function outfile(x) {
  if (x ~ /playerB/) return PATH "view.playerB"
  if (x ~ /playerA/) return PATH "view.playerA"
}

function command(new,n,cards,i) {
  if (cgidebug) print "\nCGIDEBUG entering command processing of "$0
  if (playerAprog && whoseturn ~ /playerA/) printf playerAprog" "
  if (playerBprog && whoseturn ~ /playerB/) printf playerBprog" "
  print whoseturn":  "$0
  
  # only response to a force is a force
  if (forcingperson) {
    if ($1 !~ /fo/) report( "PROTOCOL VIOLATION:  only response to force is force" )
  }

  # accept
  if ($1 ~ /^ac/) {
    if (activeprop[$2,$3,otherplayer(whoseturn)]) {
      finalrow = $2
      finalcol = $3
      agreement = 1
    } else report( "PROTOCOL VIOLATION:  accept only proposed offers" )
  }

  # propose
  if ($1 ~ /^pr/) if (kosher($2,$3)) {
    activeprop[$2,$3,whoseturn] = 1
    specialmarks[$2,$3] = "***"
  }

  # rescind proposal, unpropose
  if ($1 ~ /^unpr/) if (kosher($2,$3)) {
    if (!activeprop[$2,$3,whoseturn]) report( "PROTOCOL VIOLATION:  propose before you rescind" )
    else delete activeprop[$2,$3,whoseturn]
    for (i in sidepay)
      split(i,temp,"\034")
      if (temp[1] == $2 && temp[2] == $3 && temp[4] == whoseturn) {
	delete sidepay[i]
	print "deleting sidepayment "i" with the proposal."
      }
    for (i in sidetake)
      split(i,temp,"\034")
      if (temp[1] == $2 && temp[2] == $3 && temp[4] == whoseturn) {
	delete sidetake[i]
	print "deleting sidetaking "i" with the proposal."
      }
  }

  # search
  if ($1 ~ /^se/) if (kosher($2,$3)) {
    if (!chargeto(whoseturn)) return
    new = getcard()
    if (whoseturn == "playerA") {
      psrc[$2,$3] = psrc[$2,$3] "a"
      specialmarks[$2,$3] = "+++"
      n = sub(/\?/,new,playerA[$2,$3])
    }
    if (whoseturn == "playerB") {
      psrc[$2,$3] = psrc[$2,$3] "b"
      specialmarks[$2,$3] = "+++"
      n = sub(/\?/,new,playerB[$2,$3])
    }
    if (!n) report( "PROTOCOL VIOLATION:  no more cards to reveal" )
    resultingview = 1
  }

  # generate substitution
  if ($1 ~ /^su/) if (kosher($2,$3)) {
    if (!chargeto(whoseturn)) continue
    n = $4
    if (whoseturn == "playerA") cards = playerA[$2,$3]
    if (whoseturn == "playerB") cards = playerB[$2,$3]
    parsetotemp(cards)
    if (temp[n] ~ /[rb]/) {
	new = getcard()
	temp[n] = temp[n]">"new
    } else report( "PROTOCOL VIOLATION:  no such card to substitute" )
    cards = ""
    for (i=1; i<=nt; i++) {
	cards = cards temp[i]
    }
    if (whoseturn == "playerA") playerA[$2,$3] = cards
    if (whoseturn == "playerB") playerB[$2,$3] = cards
    resultingview = 1
  }

  # threaten row or col for playerA or playerB
  if ($1 ~ /^fo/) {
    if (whoseturn == "playerA") {
      threat = $2
      if ($3 != ".") {
	report( "PROTOCOL VIOLATION:  use . for column" )
        return
      }
      if (!kosher(threat,1)) {
	report( "PROTOCOL VIOLATION:  no such row" )
        return
      }
    }
    if (whoseturn == "playerB") {
      threat = $3
      if ($2 != ".") {
	report( "PROTOCOL VIOLATION:  use . for row" )
	return
      }
      if (!kosher(1,threat)) {
	report( "PROTOCOL VIOLATION:  no such column" )
	return
      }
    }
  }

  # ask what's wplayerBg with a proposal, whynot
  if ($1 ~ /^wh/) {
    if (!activeprop[$2,$3,whoseturn]) {
      report( "PROTOCOL VIOLATION:  propose before you ask" )
      return
    }
  }

  # ask if other has a card, haveyou
  if ($1 ~ /^ha/) {
    if (!iscard($2)) {
      report( "PROTOCOL VIOLATION:  resource must be a card" )
      return
    }
  }

  # offer a card as sidepayment to a proposal
  if ($1 ~ /^of/) {
    if (!(resources[whoseturn,$4])) {
      report( "PROTOCOL VIOLATION:  offer only what you have" )
      return
    }
    sidepay[$2,$3,$4,whoseturn] = 1
  }

  # offer to take a card as sidepayment to a proposal
  if ($1 ~ /^ot/) {
    sidetake[$2,$3,$4,whoseturn] = 1
  }

  # retract an offer a card as sidepayment to a proposal, unoffer
  if ($1 ~ /^unof/) {
    if (!sidepay[$2,$3,$4,whoseturn] && !sidepay[$2,$3,$4,whoseturn]) {
      report( "PROTOCOL VIOLATION:  no such sidepayment offered" )
      return
    }
    if (!activeprop[$2,$3,whoseturn]) {
      report( "PROTOCOL VIOLATION:  no such proposal active")
      return
    }
    delete sidepay[$2,$3,$4,whoseturn]
    delete sidetake[$2,$3,$4,whoseturn]
  }

  # warn that breakdown is imminent
  if ($1 ~ /^wa/) {
    # nothing to do here
  }

  # force breakdown for playerA or playerB
  if ($1 ~ /^fo/) {
    if (whoseturn == "playerA") {
      threat = $2
      if ($3 != ".") {
	report( "PROTOCOL VIOLATION:  use . for column" )
        return
      }
      if (!kosher(threat,1)) {
	report( "PROTOCOL VIOLATION:  no such row" )
        return
      }
      finalrow = $2
    }
    if (whoseturn == "playerB") {
      threat = $3
      if ($2 != ".") {
	report( "PROTOCOL VIOLATION:  use . for row" )
	return
      }
      if (!kosher(1,threat)) {
	report( "PROTOCOL VIOLATION:  no such column" )
	return
      }
      finalcol = $3
    }
    if (forcingperson) {
      # this is the response to a force
      agreement = 1
    }
    forcingperson = whoseturn
    lastforce = $0
  }

  if (cgidebug) print "CGIDEBUG normal return from command function"

}

function iscard(x) {
  if (x ~ /^[rb][0-9]$/) return 1
  if (x ~ /^[rb]10$/) return 1
  if (x ~ /^[rb]11$/) return 1
  if (x ~ /^[rb]12$/) return 1
  if (x ~ /^[rb]13$/) return 1
  return 0
}

function otherplayer(x) {
  if (x == "playerA") return "playerB"
  if (x == "playerB") return "playerA"
}

function addtodialogue(x) {
  print whoseturn,x,violation >> dialoguefile
  if (cgidebug) print "CGIDEBUG closing dialogue file"
  close(dialoguefile)
  if (cgidebug) print "CGIDEBUG dialogue file closed"
  system("chmod ogu+r " dialoguefile)
}

function revealsomecards(n,maxreveal) {
  maxreveal = int(10*rand())
  for (n=1; n<=maxreveal; n++) {
    revealplayerA(int(rand()*rows)+1, int(rand()*cols)+1)
    revealplayerB(int(rand()*rows)+1, int(rand()*cols)+1)
  }
}

function revealplayerA(i,j) { sub(/\?/,getcard(),playerA[i,j]) }

function revealplayerB(i,j) { sub(/\?/,getcard(),playerB[i,j]) }

function chargeto(x) {
  if (x ~ /playerA/) {
    if (playerAfreeused < playerAfree) { playerAfreeused++; return 1 }
    if (playerAcostused < playerAcost) { playerAcostused++; return 1 }
    report( "PROTOCOL VIOLATION:  sorry, no search left" )
    return 0
  }
  if (x ~ /playerB/) {
    if (playerBfreeused < playerBfree) { playerBfreeused++; return 1 }
    if (playerBcostused < playerBcost) { playerBcostused++; return 1 }
    report( "PROTOCOL VIOLATION:  sorry, no search left" )
    return 0
  }
}

function kosher(x,y,res) {
  res = 1
  if (x != int(x) || y != int(y)) res = 0
  if (x < 1 || y < 1) res = 0
  if (x > rows || y > cols) res = 0
  if (!res) report( "PROTOCOL VIOLATION:  no such row and column" )
  return res
}

function printmenu() {
   print "accept x y	accept the proposal <x,y>"
   print "prop x y	make (or repeat) a proposal"
   print "unprop x y	rescind a proposal"
   print "search x y	reveal more about a payoff"
   print "sub x y n	generate substitution for the nth card of a payoff"
   print "whynot x y	ask why not a proposal"
   print "threaten . y	threaten breakdown with column y (playerB only)"
   print "threaten x .	threaten breakdown with row x (playerA only)"
   print "warnbreak 	warn that breakdown is imminent"
   print "force . y	unilaterally breakdown (playerB only)"
   print "force x .	unilaterally breakdown (playerA only)"

   print "haveyou c	ask for the resource, c"
   print "idohave c	confirm having c"
   print "idonthave c	deny having c"
   print "offer x y c	offer a resource, conditional on agreeing to <x,y>"
   print "otake x y c	offer to take a resource, conditional on <x,y>"
   print "unoffer x y c	retract an offered resource"

}

function init() {
  rows = int(6*rand())+3
  cols = int(3*rand())+3
  maxplies = int(500*rand()+20.5)

  system("clear")
  print "\t\t\tA BETTER NEGOTIATION GAME"
  print ""
  print ""
  print ""

  if (playerAprog) { print "program for playerA is "playerAprog }
  if (playerBprog) { print "program for playerB is "playerBprog }
  print "rows " rows " (playerA controls under breakdown)"
  print "cols " cols " (playerB controls under breakdown)"
  playerAfree = int(10*rand())+1
  playerAcost = int(10*rand())+1
  playerAcount = int(20*rand())+1
  playerAfreeused = 0; playerAcostused = 0
  playerBfree = int(10*rand())+1
  playerBcost = int(10*rand())+1
  playerBcount = int(10*rand())+1
  playerBfreeused = 0; playerBcostused = 0

  # system("rm -f anne.dialogue")
  # rewrite file from top, thus saving read/write permissions
  print playerAprog " AND " playerBprog" ROUND "pairing > dialoguefile
  print "rows",rows,"cols",cols,"a new game!" > dialoguefile
  close(dialoguefile)
}

function deal(i,j,new) {
  basic = "???"
  for (i=1; i<=rows; i++) {
    for (j=1; j<=cols; j++) {
      playerA[i,j] = basic
      playerB[i,j] = basic
    }
  }
  augment(1,1)
  augment(2,2)
  augment(2,3)
  augment(3,3)
  augment(4,1)

  playerAresources = " "
  for (i=1; i<=playerAcount; i++) {
    new = getcard()
    if (!index(playerAresources," "new" ")) playerAresources = playerAresources new " "
    resources["playerA",new] = 1
  }
  gsub("^ ","",playerAresources)
  gsub(" $","",playerAresources)
  playerBresources = " "
  for (i=1; i<=playerBcount; i++) {
    new = getcard()
    if (!index(playerBresources," "new" ")) playerBresources = playerBresources new " "
    resources["playerB",new] = 1
  }
  gsub("^ ","",playerBresources)
  gsub(" $","",playerBresources)
}

function getcard(rank,color) {
  if (rand() < .5) color = "r"
  else color = "b"

  rank = int(rand()*13)+1

  return color rank
}

function augment(x,y, i,j) {
  for (i=1; i<=x; i++) {
    for (j=1; j<=y; j++) {
      playerA[i,j] = playerA[i,j] "?"
      playerB[rowrev(i),colrev(j)] = playerB[rowrev(i),colrev(j)] "?"
    }
  }
}

function rowrev(i) { return rows-i+1 }
function colrev(i) { return cols-i+1 }

function makesearch(x,y, i,result) {
  result = ""
  for (i=1; i<=x; i++) result = result "0"
  for (i=1; i<=y; i++) result = result "1"
  return result
}

function prhtml(x) {
  print x > PATH "test.html"
}

function viewweb() {
  if (whoseturn ~ /A/) prhtml("<BODY BGCOLOR=DDDDDD BACKGROUND='masks_a.jpg'>")
  else prhtml("<BODY BGCOLOR=DDDDDD BACKGROUND='masks_b.jpg'>")
  prhtml("<A HREF='anne4.expl.html'>EXPLANATION</A>")
  viewwebhow(whoseturn,0)
  prhtml("<BR><BR><BR>")
  prhtml("<I>A Better Negotiation Game</I>, designed by R.P. Loui and A.H. Jump, Summer 1997.")
  close(PATH "test.html")
}

function viewwebhow(whose,finalview, i,j,k,cards) {
  prhtml("<CENTER>")
  prhtml("<FORM METHOD='post' ACTION='anne4.cgi'>")
  prhtml("<H2>"whose"'s view<BR>")
  prhtml("<I>search</I><BR>")
  dosearch(whose)
  prhtml("<BR>")
  prhtml("<I>resources</I><BR>")
  doresources(whose)
  prhtml("</H2>")
  prhtml("<TABLE WIDTH=100%  BORDER=4>")
  prhtml("<TH colspan=1> </TH>")
  docolheaders(whose)
  for (i=1; i<=rows; i++) {
    dorowheader(whose,i)
    for (j=1; j<=cols; j++) {
      if (whose == "playerA") cards = playerA[i,j]
      if (whose == "playerB") cards = playerB[i,j]
      for (k in temp) delete temp[k]
      parsetotemp(cards)
      docell(whose,i,j,finalview)
    }
    prhtml("</TR>") # terminates the ith row
  }
  prhtml("</TABLE>")
  if (!finalview) {
    if (!forcingperson) dolegend(whose)
    else doforcelegend(whose)

    # name the form with the player getting the view
    prhtml("<SELECT name='whoseinput'>")
    prhtml("<OPTION>"whose)
    prhtml("</SELECT><BR>")
  
    prhtml("<input type=submit value=OK>")

    timestampthisform()
  }

  prhtml("</FORM>")
  if (!finalview) dolastmove(otherplayer(whose))
  prhtml("</CENTER>")
}

function timestampthisform() {
  "date" | getline date
  close("date")
  prhtml("<BR><SELECT name='datemenuval'>")
  prhtml("<OPTION>"date)
  prhtml("</SELECT>")
}

function dosearch(whose) {
  if (whose == "playerA") {
    prhtml("<FONT COLOR=gray>")
    prhtml(makesearch(playerAfreeused,playerAcostused))
    prhtml("</FONT>")
    prhtml(" ")
    prhtml(makesearch(playerAfree-playerAfreeused,playerAcost-playerAcostused))
  }
  if (whose == "playerB") {
    prhtml("<FONT COLOR=gray>")
    prhtml(makesearch(playerBfreeused,playerBcostused))
    prhtml("</FONT>")
    prhtml(" ")
    prhtml(makesearch(playerBfree-playerBfreeused,playerBcost-playerBcostused))
  } 
}

function doresources(whose, temp,i) {
  prhtml("<TABLE>")
  if (whose == "playerA") split(playerAresources,temp," ")
  if (whose == "playerB") split(playerBresources,temp," ")
  for (i=1; i in temp; i++) {
    if (substr(temp[i],1,1) == "b") prhtml("<TD BGCOLOR=909090><H2>")
    else prhtml("<TD BGCOLOR=FF5050><H2>")
    prhtml(substr(temp[i],2))
    #prhtml("<BR>")
    #textbutton("offer w/",temp[i])
    #prhtml("<BR>")
    #prhtml("<FONT=-4></FONT>")
    #prhtml("<SELECT name='offer_r,"temp[i]"'>")
    #makerowoptions()
    #prhtml("</SELECT><BR>")
    #prhtml("<SELECT name='offer_c,"temp[i]"'>")
    #makecoloptions()
    #prhtml("</SELECT>")
    #prhtml("<FONT=0></FONT>")
    prhtml("</H2></TD>")
  }
  prhtml("</TABLE>")
}

function makerowoptions( i,j) {
  prhtml("<OPTION> ")
  for (i=1; i<=rows; i++) prhtml("<OPTION>a"i)
}

function makecoloptions( i,j) {
  prhtml("<OPTION> ")
  for (j=1; j<=rows; j++) prhtml("<OPTION>r"j)
}

function makealloptions( i,j) {
  prhtml("<OPTION> ")
  for (i=1; i<=rows; i++)
    for (j=1; j<=cols; j++)
      prhtml("<OPTION>a"i"b"j)
}

function docell(whose,i,j,finalview, x,temp3) {
  if (finalview) {
    if (i == finalrow && j == finalcol) prhtml("<TD BGCOLOR=blue>")
    else prhtml("<TD>")
  } else {
    prhtml("<TD>")
    if (activeprop[i,j,"playerB"]) {
      prhtml("<FONT COLOR=green>playerB proposed</FONT>")
      x = reportsides(i,j,"playerB")
      gsub("r","<FONT COLOR=red>",x)
      gsub("b","<FONT COLOR=black>",x)
      split(x,temp3,",")
      if (temp3[1]) {
        prhtml(" <FONT COLOR=green> with </FONT>"temp3[1])
      }
      if (temp3[2]) {
        prhtml(" <FONT COLOR=green> for </FONT>"temp3[2])
      }
      prhtml("<BR>")
      #if (whose == "playerB") textbutton("*?","whynot,"i","j)
    }
    if (activeprop[i,j,"playerA"]) {
      prhtml("<FONT COLOR=yellow>playerA proposed</FONT>")
      x = reportsides(i,j,"playerA")
      gsub("r","<FONT COLOR=red>",x)
      gsub("b","<FONT COLOR=black>",x)
      split(x,temp3,",")
      if (temp3[1]) {
        prhtml(" <FONT COLOR=yellow> with </FONT>"temp3[1])
      }
      if (temp3[2]) {
        prhtml(" <FONT COLOR=yellow> for </FONT>"temp3[2])
      }
      prhtml("<BR>")
      #if (whose == "playerA") textbutton("*?","whynot,"i","j)
    } 
  }
  #optbuttons(i,j)
  prhtml("<TABLE BORDER=1>")
  prhtml("<TR>")
  for (k=1; k in temp; k++) symtable(whose,temp[k],i,j,k,temp[k-1],finalview)
  prhtml("</TR>")
  prhtml("</TABLE>")
  prhtml("</TD>")
}

function docolheaders(whose, j) {
  for (j=1; j<=cols; j++) {
    if (forcingperson && finalcol == j) prhtml("<TH BGCOLOR=green colspan=1>")
    else prhtml("<TH colspan=1>")
    prhtml("b"j)
    #if (whose == "playerB") {
      #prhtml("<BR>")
      #textbutton("!?","warn,"j",")
      #textbutton("!!","force,"j",")
    #}
    prhtml("</TH>")
  }
}

function dorowheader(whose,i) {
  prhtml("<TR>")
  if (forcingperson && finalrow == i) prhtml("<TH BGCOLOR=yellow>")
  else prhtml("<TH>")
  prhtml("a"i)
  #if (whose == "playerA") {
    #prhtml("<BR>")
    #textbutton("!?","warn,"i",")
    #textbutton("!!","force,"i",")
  #}
  prhtml("</TH>")
}

function fplayerBt2(x, ftemp) {
  split(x,ftemp,"\034")
  return "a"ftemp[1]",b"ftemp[2]
}

function doforcelegend(whose, i,j) {
  prhtml("<P>")

  # just the force option
  prhtml("<TABLE BORDER=3 BGCOLOR=AAAAFF>")
  prhtml("<TD>")
  #prhtml("<TD><B><FONT SIZE=+1>!!</FONT></B>")
  biggertextbutton("force","select")
  prhtml("<BR><SELECT name='forcemenuval'><OPTION>")
  if (whose == "playerA") for (i=1; i<=rows; i++) prhtml("<OPTION>a"i)
  if (whose == "playerB") for (j=1; j<=cols; j++) prhtml("<OPTION>b"j)
  prhtml("</SELECT></TD>")
  prhtml("</TABLE>")

  # and the message option
  prhtml("<TABLE BORDER=3 BGCOLOR=8899CC>")
  prhtml("<TD ALIGN=center>")
  #prhtml("<TD><B><FONT SIZE=+1>!!</FONT></B>")
  biggertextbutton("do nothing / say something","select")
  prhtml("<BR><TEXTAREA NAME='cheaptalk' ROWS=2 COLS=40>")
  prhtml("hello")
  prhtml("</TEXTAREA>")
  prhtml("</TD>")
  prhtml("</TABLE>")

  prhtml("<P>")
}

function dolegend(whose, x,y,i,j,k,temp3) {
  prhtml("<P>")
  prhtml("<TABLE BORDER=3 BGCOLOR=AAAAFF>")

  prhtml("<TD>")
  #prhtml("<TD><B><FONT SIZE=+1>***</FONT></B>")
  biggertextbutton("accept","select")
  prhtml("<BR><SELECT name='accmenuval'><OPTION>")
  for (x in activeprop) if (activeprop[x] && x ~ otherplayer(whose)) {
    prhtml("<OPTION>"fplayerBt2(x))
  }
  prhtml("</SELECT></TD>")

  prhtml("<TD>")
  #prhtml("<TD><B><FONT SIZE=+1>!!</FONT></B>")
  biggertextbutton("force","select")
  prhtml("<BR><SELECT name='forcemenuval'><OPTION>")
  if (whose == "playerA") for (i=1; i<=rows; i++) prhtml("<OPTION>a"i)
  if (whose == "playerB") for (j=1; j<=cols; j++) prhtml("<OPTION>b"j)
  prhtml("</SELECT></TD>")

  prhtml("</TABLE>")
  prhtml("<TABLE BORDER=3 BGCOLOR=CCEEFF>")

  prhtml("<TD>")
  #prhtml("<TD><B><FONT SIZE=+1>++</FONT></B>")
  biggertextbutton("search","select")
  prhtml("<BR><SELECT name='searchmenuval'><OPTION>")
  if (whose == "playerA" && (playerAfreeused < playerAfree || playerAcostused < playerAcost)) {
    for (i=1; i<=rows; i++) for (j=1; j<=cols; j++)
      if (playerA[i,j] ~ /\?/) prhtml("<OPTION>a"i",b"j)
  }
  if (whose == "playerB" && (playerBfreeused < playerBfree || playerBcostused < playerBcost)) {
    for (i=1; i<=rows; i++) for (j=1; j<=cols; j++)
      if (playerB[i,j] ~ /\?/) prhtml("<OPTION>a"i",b"j)
  }
  prhtml("</SELECT></TD>")

  prhtml("<TD>")
  #prhtml("<TD><B><FONT SIZE=+1>!!</FONT></B>")
  biggertextbutton("substitute","select")
  prhtml("<BR><SELECT name='substmenuval'><OPTION>")
  for (i=1; i<=rows; i++) for (j=1; j<=cols; j++) {
    if (whose == "playerA") {
      x = playerA[i,j]
      y = (playerAcost - playerAcostused) + (playerAfree  - playerAfreeused)
    }
    if (whose == "playerB") {
      x = playerB[i,j]
      y = (playerBcost - playerBcostused) + (playerBfree  - playerBfreeused)
    }
    if (y > 0 && x ~ /\?/ && x ~ /[0-9]/) {
      parsetotemp(x)
      for (k=1; k in temp; k++) if (temp[k] !~ /\?/) prhtml("<OPTION>a"i",b"j",#"k)
    }
  }
  prhtml("</SELECT></TD>")

  prhtml("<TD WIDTH=60>")
  prhtml("</TD>")

  prhtml("<TD>")
  #prhtml("<TD><B><FONT SIZE=+1>>></FONT></B>")
  biggertextbutton("propose","select")
  prhtml("<BR><SELECT name='propmenuval'><OPTION>")
  for (i=1; i<=rows; i++) for (j=1; j<=cols; j++)
    if (!activeprop[i,j,whose])
      prhtml("<OPTION>a"i",b"j)
  prhtml("</SELECT></TD>")

  prhtml("<TD>")
  #prhtml("<TD><B><FONT SIZE=+1><<</FONT></B>")
  biggertextbutton("unpropose","select")
  prhtml("<BR><SELECT name='unpropmenuval'><OPTION>")
  for (x in activeprop) if (activeprop[x] && x ~ whose) {
    prhtml("<OPTION>"fplayerBt2(x))
  }
  prhtml("</SELECT></TD>")

  prhtml("</TABLE>")
  prhtml("<TABLE BORDER=3 BGCOLOR=CCEEFF>")

  prhtml("<TD>")
  #prhtml("<TD><B><FONT SIZE=+1>!!</FONT></B>")
  biggertextbutton("offer to give a resource","select")
  prhtml("<BR><SELECT name='offermenuval1'><OPTION>")
  for (x in resources) if (resources[x] && x ~ whose) {
    split(x,temp3,"\034")
    gsub("r","red ",temp3[2])
    gsub("b","black ",temp3[2])
    prhtml("<OPTION>"temp3[2])
  }
  prhtml("</SELECT> with ")
  prhtml("<SELECT name='offermenuval2'><OPTION>")
  for (i=1; i<=rows; i++) for (j=1; j<=cols; j++) {
    prhtml("<OPTION>a"i",b"j)
  }
  prhtml("</SELECT></TD>")

  prhtml("<TD WIDTH=20>")
  prhtml("</TD>")

  prhtml("<TD>")
  #prhtml("<TD><B><FONT SIZE=+1>!!</FONT></B>")
  biggertextbutton("offer to take a resource","select")
  prhtml("<BR><SELECT name='otakemenuval1'><OPTION>")
  prhtml("<OPTION>red")
  prhtml("<OPTION>black")
  prhtml("</SELECT>")
  prhtml("<SELECT name='otakemenuval2'><OPTION>")
  for (i=1; i<=13; i++) prhtml("<OPTION>"i)
  prhtml("</SELECT> with ")
  prhtml("<SELECT name='otakemenuval3'><OPTION>")
  for (i=1; i<=rows; i++) for (j=1; j<=cols; j++) {
    prhtml("<OPTION>a"i",b"j)
  }
  prhtml("</SELECT></TD>")

  prhtml("</TABLE>")
  prhtml("<TABLE BORDER=3 BGCOLOR=CCEEFF>")

  prhtml("<TD>")
  #prhtml("<TD><B><FONT SIZE=+1>!?</FONT></B>")
  biggertextbutton("threaten","select")
  prhtml("<BR><SELECT name='threatenmenuval'><OPTION>")
  if (whose == "playerA") for (i=1; i<=rows; i++) prhtml("<OPTION>a"i)
  if (whose == "playerB") for (j=1; j<=cols; j++) prhtml("<OPTION>b"j)
  prhtml("</SELECT></TD>")

  prhtml("</TABLE>")
  prhtml("<TABLE BORDER=3 BGCOLOR=EEEEFF>")

  prhtml("<TD>")
  #prhtml("<TD><B><FONT SIZE=+1>*?</FONT></B>")
  biggertextbutton("ask why not?","select")
  prhtml("<BR><SELECT name='whynotmenuval'><OPTION>")
  for (x in activeprop) if (activeprop[x] && x ~ whose) {
    prhtml("<OPTION>"fplayerBt2(x))
  }
  prhtml("</SELECT></TD>")

  prhtml("<TD>")
  #prhtml("<TD><B><FONT SIZE=+1>*?</FONT></B>")
  biggertextbutton("ask do you have?","select")
  prhtml("<BR><SELECT name='haveyoumenuval1'><OPTION>")
  prhtml("<OPTION>red")
  prhtml("<OPTION>black")
  prhtml("</SELECT>")
  prhtml("<SELECT name='haveyoumenuval2'><OPTION>")
  for (i=1; i<=13; i++) prhtml("<OPTION>"i)
  prhtml("</SELECT></TD>")

  prhtml("</TABLE>")
  prhtml("<TABLE BORDER=3 BGCOLOR=EEEEFF>")

  prhtml("<TD>")
  biggertextbutton("answer yes","select")
  prhtml("</TD>")

  prhtml("<TD>")
  biggertextbutton("answer no","select")
  prhtml("</TD>")

  prhtml("</TABLE>")
  prhtml("<TABLE BORDER=3 BGCOLOR=8899CC>")

  prhtml("<TD ALIGN=center>")
  #prhtml("<TD><B><FONT SIZE=+1>!!</FONT></B>")
  biggertextbutton("do nothing / say something","select")
  prhtml("<BR><TEXTAREA NAME='cheaptalk' ROWS=2 COLS=40>")
  prhtml("hello")
  prhtml("</TEXTAREA>")
  prhtml("</TD>")

  prhtml("</TABLE>")

  prhtml("<P>")
  textbutton("REVIEW THE ENTIRE DIALOGUE","select")
  prhtml("<P>")
}

function dolastmove(x, lastmove1,lastmove2) {
  while ((getline < dialoguefile)>0) {
    gsub(/%0D%0A/," ... ",$0) 
    if ($2 == "from") $2 = "(did nothing) from"
    if ($0 == " AND  ROUND ") $0 = ""
    $1 = $1":"
    # censor the first line of anne.dialogue
    lastmove1 = lastmove2
    lastmove2 = $0
  }
  close(dialoguefile)
  prhtml("<BR><H4><I>last moves were:</I><BR>")
  prhtml(lastmove1)
  prhtml("<BR>")
  prhtml(lastmove2)
  prhtml("</H4>")
  prhtml("<H4>")
  #prhtml("<a href='anne.dialogue'>ENTIRE DIALOGUE<BR></a>(you must reload)")
  prhtml("</H4>")
}

function optbuttons(i,j) {
  if (activeprop[i,j,"playerB"]) textbutton("***","accept,"i","j)
  else if (activeprop[i,j,"playerA"]) textbutton("<<","unprop,"i","j)
  else textbutton(">>",">>"i","j)
  if (playerA[i,j] ~ /\?/) textbutton("++","search,"i","j)
  prhtml("<BR>")
}

function textbutton(x,y, result) {
  result = "<input type='radio' name='how' value='"x y"'>"
  result = result "<FONT SIZE=-9>" x "</FONT>"
  prhtml(result)
}

function biggertextbutton(x,y, result) {
  result = "<input type='radio' name='how' value='"x y"'>"
  result = result "<FONT SIZE=+1>" x "</FONT>"
  prhtml(result)
}

function symtable(whose,x,r,c,n,lastx,finalview, i,exchanges,y,red,green,blue,searchrem) {
  searchrem = 0
  if (whose == "playerA" && (playerAfreeused < playerAfree || playerAcostused < playerAcost)) searchrem = 1
  if (whose == "playerB" && (playerBfreeused < playerBfree || playerBcostused < playerBcost)) searchrem = 1
  split(x,exchanges,">")
  for (i=1; i in exchanges; i++) {
    y = exchanges[i]
    if (y == "?") {
      if (lastx == "?") prhtml("<TD><H2>_</H2></TD>")
      else {
	prhtml("<TD>")
        if (searchrem) textbutton("","search,"r","c)
	else prhtml("<H2>_</H2>")
	prhtml("</TD>")
      }
      continue
    }
    if (substr(y,1,1) == "b") { red = 90; green = 90; blue = 90 }
    else if (substr(y,1,1) == "r") { red = "FF"; green = 50; blue = 50 }
    else {red = 10; green = 10; blue = 10 }
    if (i == 1) {
      prhtml("<TD BGCOLOR="red green blue"><H2>")
      prhtml(substr(y,2))
      if (!finalview) {
	prhtml("<BR>")
        if (whose == "playerA" && (playerAfreeused < playerAfree || playerAcostused < playerAcost)) textbutton("","sub,"r","c",#"n)
        if (whose == "playerB" && (playerBfreeused < playerBfree || playerBcostused < playerBcost)) textbutton("","sub,"r","c",#"n)
      }
      prhtml("</H2></TD>")
    } else {
      prhtml("<TD><TABLE><TR><TD>s</TD></TR><TR>")
      prhtml("<TD BGCOLOR="red green blue"><H4>"substr(y,2)"</H4></TD>")
      prhtml("</TR></TABLE></TD>")
    }
  }
}


function viewgui( i,j,ps) {
  system("clear")
  printf "    "
  for (j=1; j<=cols; j++) printf "%"maxformat[j]"s",j
  print ""
  for (i=1; i<=rows; i++) {
    printf "%4s",i
    for (j=1; j<=cols; j++) {
      ps = specialmarks[i,j] psrc[i,j]
      if (activeprop[i,j,"playerA"]) ps = ps "1" reportsides(i,j,"playerA")
      if (activeprop[i,j,"playerB"]) ps = ps "2" reportsides(i,j,"playerB")
      if (!ps) ps = "."
      printf "%"maxformat[j]"s",ps
    }
    print ""
    printf "%4s"," "
    for (j=1; j<=cols; j++) printf "%"maxformat[j]"s",playerA[i,j]
    print ""
    printf "%4s"," "
    for (j=1; j<=cols; j++) printf "%"maxformat[j]"s",playerB[i,j]
    print ""
  }
  print "playerA's search: " makesearch(playerAfree-playerAfreeused,playerAcost-playerAcostused)
  print "playerB's search: " makesearch(playerBfree-playerBfreeused,playerBcost-playerBcostused)
  system("sleep 3")
  delete specialmarks
}

function reportsides(r,c,who, j,temp3,res) {
  res = ""
  for (j in sidepay) {
    split(j,temp3,"\034")
    if (r == temp3[1] && c == temp3[2] && temp3[4] == who) res = res temp3[3]
  }
  res = res","
  for (j in sidetake) {
    split(j,temp3,"\034")
    if (r == temp3[1] && c == temp3[2] && temp3[4] == who) res = res temp3[3]
  }
  if (length(res) == 1) res = ""
  return res
}

function view(who,where, max,i,j,temp2) {
  # format is the longest string
  if (who ~ /playerA/) {

    for (j=1; j<=cols; j++) {
      max = 0
      for (i=1; i<=rows; i++) {
        if (length(playerA[i,j]) > max) max = length(playerA[i,j])
      }
      max++
      if (max > maxformat[j]) maxformat[j] = max
      format[j] = "%"max"s"
    }

    print "" > where
    print "playerA's resources: " playerAresources > where
    print "playerA's search: " makesearch(playerAfree-playerAfreeused,playerAcost-playerAcostused) > where
    print "playerA's payoffs (preferring upper left)" > where
    printf "%4s","" > where
    for (j=1; j<=cols; j++) { printf format[j],j > where}
    print "" > where
    for (i=1; i<=rows; i++) {
      printf "%4s",i" " > where
      for (j=1; j<=cols; j++) {
        printf format[j],playerA[i,j] > where
      }
      print "" > where
    }

  }

  if (who ~ /playerB/) {

    for (j=1; j<=cols; j++) {
      max = 0
      for (i=1; i<=rows; i++) {
        if (length(playerB[i,j]) > max) max = length(playerB[i,j])
      }
      max++
      if (max > maxformat[j]) maxformat[j] = max
      format[j] = "%"max"s"
    }

    print "" > where
    print "playerB's resources: " playerBresources > where
    print "playerB's search: " makesearch(playerBfree-playerBfreeused,playerBcost-playerBcostused) > where
    print "playerB's payoffs (preferring lower right)" > where
    printf "%4s","" > where
    for (j=1; j<=cols; j++) { printf format[j],j > where }
    print "" > where
    for (i=1; i<=rows; i++) {
      printf "%4s",i" " > where
      for (j=1; j<=cols; j++) {
        printf format[j],playerB[i,j] > where
      }
      print "" > where
    }

  }

  for (i in activeprop) if (activeprop[i]) {
    split(i,temp,"\034")
    if (temp[3] == who) {
      print "\tyou have proposed: "temp[1],temp[2] > where
      for (j in sidepay) {
        split(j,temp2,"\034")
        if (temp[1] == temp2[1] && temp[2] == temp2[2] && temp2[4] == who) {
	  print "\t\twith sidepayment "temp2[3] > where
	}
      }
      for (j in sidetake) {
        split(j,temp2,"\034")
        if (temp[1] == temp2[1] && temp[2] == temp2[2] && temp2[4] == who) {
	  print "\t\twith sidetaking "temp2[3] > where
        }
      }
    }
  }
  for (i in activeprop) if (activeprop[i]){
    split(i,temp,"\034")
    if (temp[3] != who) {
      print "\tproposed to you: "temp[1],temp[2] > where
      for (j in sidepay) {
        split(j,temp2,"\034")
        if (temp[1] == temp2[1] && temp[2] == temp2[2] && temp2[4] == otherplayer(who)) {
	  print "\t\twith sidepayment "temp2[3] > where
        }
      }
      for (j in sidetaking) {
        split(j,temp2,"\034")
        if (temp[1] == temp2[1] && temp[2] == temp2[2] && temp2[4] == otherplayer(who)) {
	  print "\t\twith sidetaking "temp2[3] > where
        }
      }
    }
  }

  if (forcingperson) {
    printf force" has left the negotiation, forcing " > where
    if (forcingperson == "playerA") print "row "finalrow > where
    if (forcingperson == "playerB") print "col "finalcol > where
  }

  close(where)
  if (where !~ /stdout/) system("chmod ogu+r "where)

}

function revealremaining(i,new) {
  for (i in playerA) {
    while (playerA[i] ~ /\?/) {
      new = getcard()
      sub(/\?/,new,playerA[i])
    }
  }
  for (i in playerB) {
    while (playerB[i] ~ /\?/) {
      new = getcard()
      sub(/\?/,new,playerB[i])
    }
  }
}

function sumcells(i,j,k,temp,cell,total) {
  for (i=1; i<=rows; i++) {
    for (j=1; j<=cols; j++) {
      total = 0
      cell = playerA[i,j]
      split(cell,temp,"[rb]")
      for (k in temp) 
	if (temp[k] < pilecardmin[1,i,j]) temp[k] = pilecardmin[1,i,j]
      for (k in temp) total += temp[k]
      playerAval[i,j] = total

      total = 0
      cell = playerB[i,j]
      split(cell,temp,"[rb]")
      for (k in temp) 
	if (temp[k] < pilecardmin[1,i,j]) temp[k] = pilecardmin[1,i,j]
      for (k in temp) total += temp[k]
      playerBval[i,j] = total
    }
  }
}

function reportsums() {
  reportplayerA("/dev/stdout")
  reportplayerB("/dev/stdout")
  reportplayerA(outfile("playerA"))
  reportplayerB(outfile("playerB"))
}

function reportplayerA(where, i,j) {
  playerAmax = 1
  print "" > where
  print "\t\tplayerA's final payoffs" > where
  printf "\t\t%4s","" > where
  for (j=1; j<=cols; j++) { printf "%4s",j > where }
  print "" > where
  for (i=1; i<=rows; i++) {
    printf "\t\t%4s",i" " > where
    for (j=1; j<=cols; j++) {
      printf "%4s",playerAval[i,j] > where
      if (playerAval[i,j] > playerAmax) playerAmax = playerAval[i,j]
    }
    print "" > where
  }
  close(where)
  if (where !~ /stdout/) system("chmod ogu+r "where)
}

function reportplayerB(where, i,j) {
  playerBmax = 1
  print "" > where
  print "\t\tplayerB's final payoffs" > where
  printf "\t\t%4s","" > where
  for (j=1; j<=cols; j++) { printf "%4s",j > where }
  print "" > where
  for (i=1; i<=rows; i++) {
    printf "\t\t%4s",i" " > where
    for (j=1; j<=cols; j++) {
      printf "%4s",playerBval[i,j] > where
      if (playerBval[i,j] > playerBmax) playerBmax = playerBval[i,j]
    }
    print "" > where
  }
  close(where)
  if (where !~ /stdout/) system("chmod ogu+r "where)
}

function reportvalue(x,y) {
  playerAgets = playerAval[x,y] - playerAcostused
  playerBgets = playerBval[x,y] - playerBcostused
  print ""
  print "\t\t\tplayerA gets "playerAgets
  print "\t\t\tplayerB gets "playerBgets
  print "\t\t\tplayerA gets "playerAgets >> outfile("playerA")
  print "\t\t\tplayerB gets "playerBgets >> outfile("playerB")

  if (webout) {
    prhtml("<P><CENTER>")
    if (playerAcostused) prhtml("<I>playerA's search cost "playerAcostused"</I><BR>")
    if (playerBcostused) prhtml("<I>playerB's search cost "playerBcostused"</I><BR>")
    prhtml("<H2>")
    prhtml("<P>playerA gets "playerAgets" ")
    prhtml("(" int(.5+100*playerAgets/playerAmax) " percent of best)")
    prhtml("<P>playerB gets "playerBgets" ")
    prhtml("(" int(.5+100*playerBgets/playerBmax) " percent of best)")
    prhtml("</H2>")
    prhtml("<BR><BR>HOW HAPPY IS A?<BR>")
    prhtml("<FORM><SELECT name='howhappyA'>")
    for (i=1; i<=9; i++) prhtml("<OPTION>"i)
    prhtml("</SELECT>")
    prhtml("<BR><BR>HOW HAPPY IS B?<BR>")
    prhtml("<SELECT name='howhappyB'>")
    for (i=1; i<=9; i++) prhtml("<OPTION>"i)
    prhtml("</SELECT>")
    prhtml("<BR><BR><input type=submit value=OK>")
    timestampthisform()
    prhtml("</FORM>")
    prhtml("</CENTER>")
    prhtml("<BR><BR><BR><BR><pre>")
    prhtml("THE WHOLE DIALOGUE:")
    close(dialoguefile)
    while (getline < dialoguefile) {
      if ($1 ~ /player/) { 
	$1 = $1":"
        prhtml(++movenum".  "$0)
      }
    }
    close(dialoguefile)
    prhtml("</pre>")
  }
}

function doexchanges(i,j,max,maxval,cards,k,l,exchanges,thisval,thiscolor,oppcolor,oppcard) {
  for (i=1; i<=rows; i++) {
    for (j=1; j<=cols; j++) {

      cards = playerA[i,j]
      for (k in temp) delete temp[k]
      parsetotemp(cards)
      for (k=1; k<=nt; k++) {
        pilecardmin[1,i,j] = 0
	for (l in exchanges) delete exchanges[l]
	split(temp[k],exchanges,">")
	max = exchanges[1]
	for (l=1; l in exchanges; l++) {
	  thisval = substr(exchanges[l],2)
	  maxval = substr(max,2)
	  if (thisval+0 > maxval+0) max = exchanges[l]
	  if (thisval+0 > pilecardmin[1,i,j]) pilecardmin[1,i,j] = thisval+0
	  thiscolor = substr(exchanges[1],1,1)
	  if (thiscolor == "b") oppcolor = "r"
	  else oppcolor = "b"
	  oppcard = oppcolor thisval
	  if (!(resources["playerA",oppcard])) break
	  if (l+1 in exchanges) print oppcard " permits playerA an exchange at "i,j
	}
	temp[k] = max
      }
      playerA[i,j] = ""
      for (k=1; k<=nt; k++) playerA[i,j] = playerA[i,j] temp[k]

      cards = playerB[i,j]
      for (k in temp) delete temp[k]
      parsetotemp(cards)
      for (k=1; k<=nt; k++) {
        pilecardmin[2,i,j] = 0
	for (l in exchanges) delete exchanges[l]
	split(temp[k],exchanges,">")
	max = exchanges[1]
	for (l=1; l in exchanges; l++) {
	  thisval = substr(exchanges[l],2)
	  maxval = substr(max,2)
	  if (thisval+0 > maxval+0) max = exchanges[l]
	  if (thisval+0 > pilecardmin[2,i,j]) pilecardmin[2,i,j] = thisval+0
	  thiscolor = substr(exchanges[1],1,1)
	  if (thiscolor == "b") oppcolor = "r"
	  else oppcolor = "b"
	  oppcard = oppcolor thisval
	  if (!(resources["playerB",oppcard])) break
	  if (l+1 in exchanges) print oppcard " permits playerB an exchange at "i,j
	}
	temp[k] = max
      }
      playerB[i,j] = ""
      for (k=1; k<=nt; k++) playerB[i,j] = playerB[i,j] temp[k]

    }
  }
}

function parsetotemp(cards) {
  # cards might be "r12>r7>b8b5???"
  # sets the global vals temp and nt
  nt = 0
  while (cards) {
    first = substr(cards,1,1)
    take = 1
    while (substr(cards,take+1,1) ~ /[0-9>]/) {
      take++
      if (substr(cards,take,1) == ">") take++
    }
    temp[++nt] = substr(cards,1,take)
    cards = substr(cards,take+1)
  }
}

function traderesources(temp,i,benfactor,beneficiary,card) {

  for (i in sidepay) {
    split(i,temp,"\034")
    if (temp[1] == finalrow && temp[2] == finalcol) {
      benefactor = temp[4]
      beneficiary = otherplayer(benefactor)
      card = temp[3]
      delete resources[benefactor,card]
      resources[beneficiary,card] = 1
      if (beneficiary == "playerA") playerAresources = playerAresources " " card
      if (beneficiary == "playerB") playerBresources = playerBresources " " card
      if (benefactor == "playerA") {
	playerAresources = " " playerAresources
	gsub(" "card,"",playerAresources)
	gsub("^ ","",playerAresources)
      }
      if (benefactor == "playerB") {
	playerBresources = " " playerBresources
	gsub(" "card,"",playerBresources)
	gsub("^ ","",playerBresources)
      }
      print "TRADE: " benefactor " gives " beneficiary " " card
    }
  }

  for (i in sidetake) {
    split(i,temp,"\034")
    if (temp[1] == finalrow && temp[2] == finalcol) {
      beneficiary = temp[4]
      benefactor = otherplayer(beneficiary)
      card = temp[3]
      delete resources[benefactor,card]
      resources[beneficiary,card] = 1
      if (beneficiary == "playerA") playerAresources = playerAresources " " card
      if (beneficiary == "playerB") playerBresources = playerBresources " " card
      if (benefactor == "playerA") {
	playerAresources = " " playerAresources
	gsub(" "card,"",playerAresources)
	gsub("^ ","",playerAresources)
      }
      if (benefactor == "playerB") {
	playerBresources = " " playerBresources
	gsub(" "card,"",playerBresources)
	gsub("^ ","",playerBresources)
      }
      print "TRADE: " benefactor " gives " beneficiary " " card
    }
  }
}

function askhowhappy() {
  if (playerAprog) {
    playerAcom = playerAprog".howhappy playerA"
    playerAcom | getline happyplayerA
    close(playerAcom)
  } else {
    printf "how happy is playerA with this outcome?"
    getline happyplayerA
  }
  if (playerBprog) {
    playerBcom = playerBprog".howhappy playerB"
    playerBcom | getline happyplayerB
    close(playerBcom)
  } else {
    printf "how happy is playerB with this outcome?"
    getline happyplayerB
  }
  if (happyplayerA < 0) happyplayerA = 0
  if (happyplayerB < 0) happyplayerB = 0
  if (happyplayerA > 10) happyplayerA = 10
  if (happyplayerB > 10) happyplayerB = 10
}

function score() {
  print "SCORE for PLAYER1:  ", happyplayerA, happyplayerB, playerAgets, playerAgets/playerAmax
  print "SCORE for PLAYER2:  ", happyplayerB, happyplayerA, playerBgets, playerBgets/playerBmax
  if (playerAprog) print playerAprog, "SCORE for PLAYER1:  ", happyplayerA, happyplayerB, playerAgets, playerAgets/playerAmax >> "playerA.scores"
  if (playerBprog) print playerBprog, "SCORE for PLAYER2:  ", happyplayerB, happyplayerA, playerBgets, playerBgets/playerBmax >> "playerA.scores"
}

function makesocialrecord() {
  if (playerAprog && playerBprog) print playerAprog, happyplayerA, playerBprog, happyplayerB >> PATH "playerA.socialrecord"
  if (playerBprog) {
    system("cp -f " dialoguefile " " PATH playerBprog".lastdialogue."pairing)
  }
  if (playerAprog) {
    system("cp -f " dialoguefile " " PATH playerAprog".lastdialogue."pairing)
  }
  system("chmod ogu+r " PATH "playerA.socialrecord " PATH "*.lastdialogue.*")
}